Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

Mouse.removeListener()

Доступность

Flash Player 6.

Синтаксис

Mouse.removeListener (listener:Object) : Boolean

Параметры

listener Объект.

Возвращает

Если объект listener Успешно удален, метод возвращет true; если listener по каким-либо причинам удалить не удалось (например, если объект listener являлся листенером не объекта Mouse), метод возвратит false.

Описание

Метод; удаляет объект, предварительно зарегистрированный как листенер с помощью addListener(), из списка листенеров данного.

Пример

В примере ниже на Сцену аттачатся три кнопки и пользователь может рисовать курсором в пределах SWF ролика. Первая кнопка стирает нарисованное. Вторая — удаляет листенер, то есть пользователь уже не может рисовать. Третья кнопка добавляет листенер после удаления, то есть пользователь снова может рисовать. Добавьте следующий код в первый кадр основного Таймлайна:

/* Добавьте экземпляр компонента Button в Библиотеку. 
   Аттачим и позиционируем три кнопки на Сцену. */
this.createClassObject(mx.controls.Button, "clear_button", this.getNextHighestDepth(), {_x:10, _y:10, label:'clear'});
this.createClassObject(mx.controls.Button, "stopDrawing_button", this.getNextHighestDepth(), {_x:120, _y:10, label:'stop drawing'});
this.createClassObject(mx.controls.Button, "startDrawing_button", this.getNextHighestDepth(), {_x:230, _y:10, label:'start drawing'});
startDrawing_button.enabled = false;
//
this.createEmptyMovieClip("canvas_mc", this.getNextHighestDepth());
var mouseListener:Object = new Object();
mouseListener.onMouseDown = function() {
  this.isDrawing = true;
  canvas_mc.lineStyle(2, 0xFF0000, 100);
  canvas_mc.moveTo(_xmouse, _ymouse);
};
mouseListener.onMouseMove = function() {
  if (this.isDrawing) {
    canvas_mc.lineTo(_xmouse, _ymouse);
  }
  updateAfterEvent();
};
mouseListener.onMouseUp = function() {
  this.isDrawing = false;
};
Mouse.addListener(mouseListener);
var clearListener:Object = new Object();
clearListener.click = function() {
  canvas_mc.clear();
};
clear_button.addEventListener("click", clearListener);
//
var stopDrawingListener:Object = new Object();
stopDrawingListener.click = function (evt:Object) {
  Mouse.removeListener(mouseListener);
  evt.target.enabled = false;
  startDrawing_button.enabled = true;
};
stopDrawing_button.addEventListener("click", stopDrawingListener);
var startDrawingListener:Object = new Object();
startDrawingListener.click = function (evt:Object) {
  Mouse.addListener(mouseListener);
  evt.target.enabled = false;
  stopDrawing_button.enabled = true;
};
startDrawing_button.addEventListener("click", startDrawingListener);

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление